sed 笔记

第一个语法，最简单也是最常用的：

sed 's/old/new/' file

• s：sed 的操作命令；
• /../../ ：限定符，限定符也可以用其他符号，比如叹号：sed 's!root!ROOT!' /etc/passwd
• old：查找字符串
• new：替换的新字符串

删除命令也是非常常用的，用来删除匹配的行。删除命令是：d。

例，删除匹配到“root”的行：

sed '/root/d' /etc/passwd

还可以删除不匹配的行，例，删除不匹配 com.cn 的行：

sed -i '/com.cn$/!d' file

可以为删除指定地址范围，如，删除 1~10 行：

sed '1,10d'

表示从 20 行开始删到行尾：

sed '20,$d'

表示从第一行开始一直删除到第一次匹配到字符“c”的行：

sed '1,/c/d'

表示删除空行：

sed '/^$/d'

如何让 sed 一次执行多个操作。

方法 1，使用 -e 参数：

sed  -e 's/,/\t/g' -e 's/(//g' -e 's/)//g'

方法 2，指定 sed 脚本：

s/root/ROOT/
s/\/bash/\/zsh/ # 替换 shell

注：“#”是 sed 的注释符。

然后通过 -f 参数指定：

sed -f /tmp/sed.sed /etc/passwd

方法 3，使用分号做命令的分割符：

sed 's/,/\t/g;s/(//g;s/)//g'

方法 4，使用 shell 本身的分行功能：

sed 's/,/\t/g
> s/(//g
> s/)//g' test

next 是一个控制流程的命令，负责读取”下一行“，可以用于完成”删除 xx 下一行内容“这样的任务。

例，如果匹配”nobody“的下一行是空白行，则删除：

sed '/nobody/{n;/^$/d}' text

w 用于写入到文件，如

sed 's/root/ROOT/w new' < /etc/passwd

r 则是将其他文件内容读入当前模式空间：

sed -n '/root/r /etc/hosts' /etc/passwd

/p 命令，将操作的行进行打印输出，但是输出内容时并不会清理其他输出，所以可能导致重复的输出，一般来说都搭配 -n 参数使用：

sed -n 's/root/ROOT/p' /etc/passwd

打印行号用 = 命令，也可以配合 -n 使用：

sed -n '/root/=' /etc/passwd

sed 可以在指定范围内做多个操作，多个操作用大括号包围起来，如：

/root/,/gdm/{
s/\/nologin/\/NOLOGIN/g
/adm/d
}

打印 10 行后结束运行：

sed '10 q' /etc/passwd

sed 默认是不会修改文本源本身的内容的，如果要把处理结果直接写入源文件，可以用 -i 参数：

sed -i 命令

但要尽量避免直接操作，否则 sed 命令一旦写错，就导致源文本被彻底修改。

sed 默认是逐行处理，处理每一行时不会考虑换行符，在处理之后才会加上，所以以下方法替换换行符是没任何用的：

sed 's/\n//g'

前面说过，可以用“N”读取下一行，所以网上出现了这种方式替换换行：

sed 'N;s/\n//g'

不过，如果是多行情况下，这种替换就会导致出现每两行被合并到一行的现象：

$ cat file
a
b
c
d
$ sed 'N;s/\n//g' file
ab
cd

sed 语法中，冒号开头的可以作为标签，t 作为跳转指令，通过这两个结合，不断地读下一行来替换即可：

$ sed ':x;N;s/\n/,/g;tx' file   # 将换行符号替换成英文逗号；“x”是标签名，“tx”是跳转到标签“x”
a,b,c,d

通常 sed 会只读一行到模式空间中，但也可以让它读取多行，假如有这样一段文本：

Published software should be free software. To make it free software, you need to release it under a free software license. We normally use the GNU
General Public License (GNU GPL), but occasionally we use other free software licenses. We use only licenses that are compatible with the GNU GPL for GNU software.

我想将”GNU General Public License (GNU GPL)“替换为”GPL“，但”GNU“后面出现了换行，所以无法直接替换。

sed 的”N“命令可以把下一行的内容加入到当前的模式空间中，所以借助”N“命令就可以完成以上需求：

sed '/GNU$/{N;s/GNU\nGeneral Public License (GNU GPL)/GPL/}'

如果匹配到”GNU“结尾的行，就执行”N“命令把下一行内容追加到当前模式空间中后执行替换操作。替换后如下：

Published software should be free software. To make it free software, you need to release it under a free software license. We normally use the GPL, but occasionally we use other free software licenses. We use only licenses that are compatible with the GNU GPL for GNU software.

如下文本：

aaaaaa









aaaaaaaaaaaaaaaaaaa




aaaaa

aaa

现在想每个非空行之间只保留一个空行，这里用到“D”命令：

sed '/^$/{N;/^\n$/D}'

为什么不是”d“？修改成”d“以后，执行结果如下：

$ sed '/^$/{N;/^\n$/d}' test
aaaaaa

aaaaaaaaaaaaaaaaaaa
aaaaa

aaa

用”d“命令时，遇到空行就读入下一行到模式空间，如果新加入模式空间的这行也是空行，那么正则”^$“是可以成功匹配，接着整个模式都被删除了——所以两行都没有了，也就是说如果空行个数是奇数，那可以保留一行空行。

现在修改成”D“命令就正常了：

$ sed '/^$/{N;/^\n$/D}' test
aaaaaa

aaaaaaaaaaaaaaaaaaa

aaaaa

aaa

因为”D“只会删除当前模式空间中第一个匹配到的行，也就是两个空行合并到模式空间中，只有其中一行会被删除。

”p“命令会将当前模式空间内容全部打印出来，而”P“只会打印模式空间中第一行命令：

$ seq 10 | sed -n '/[0-9]/{N;P}'
1
3
5
7
9

当匹配到数字行时，会将下一行也读入当前模式空间，并且只打印模式空间第一行，所以实现了每隔一行打印一次。

sed 会把每行内容都往模式空间中保存，除了模式空间，还有个保存空间可以使用。

h 或 H：将模式空间的内容复制到保存空间 G：将保持空间的内容复制到模式空间 x：交换保持空间和模式空间的内容

例，将下面文本中带“1”的行和带“2”的行交换顺序：

1
2
11
22
111
222

命令如下：

$ sed '/1/{h;d};/2/{G}' num_file
2
1
22
11
222
111

命令说明： 1、当匹配到“1”时，先执行“h”，将模式空间内容保存到保持空间，然后删除当前模式空间的内容；

2、当匹配到“2”时，执行“G”从保持空间中将数据复制到模式空间。